Anillo 3 - Original
An interactive fiction by Mel Hython (2009) - the Inform 7 source text
Contents
Previous
Next
Complete text
Section 1 - Hiedra
To say montumul:
if monticulo is inicial:
say "montículo";
otherwise:
say "túmulo".
A hiedra espinosa is fixed in place. "[if hiedra is not despejada]Una hiedra espinosa recubre gran parte de las piedras que conforman un montículo en este lugar.[otherwise]La hiedra recubre buena parte del [montumul] pero la parte que has arrancado deja ver un acceso a su interior, hacia abajo.[end if]".
The description of hiedra is "Esta es una de esas planta malévolas del pantano Hapawa. No es una hiedra, ni una zarza exactamente, sino una especie de híbrido entre ambas, probablemente venenosa, y en cualquier caso una suerte de monstruo entre las plantas. Ésta se ha extendido mucho, debe ser muy antigua.";
Hiedra espinosa is in Pantano23.
Hiedra can be despejada. Hiedra is not despejada.
Understand "arbusto" or "arbustos" or "espinos" or "espino" as hiedra when the location is Pantano23.
[ Avisar que es espinoso ]
Instead of doing anything except examining or smelling or cutting with hiedra when guantes is not worn:
say "La hiedra es demasiado peligrosa como para manipularla sin protección. Podrías perder el control sobre tu portador debido al dolor que sufra, o incluso perderlo a él si se envenena demasiado.".
Understand "podar [a thing]" or "poda [a thing]" as cutting when the location is Pantano23.
[ Para cortarla hace falta un machete ]
Instead of cutting hiedra when machete is not carried:
say "No parece mala idea podar la hiedra, pero sin alguna clase de herramienta cortante va a resultar imposible.".
[ Con el machete sí ]
Instead of cutting hiedra when machete is carried:
say "Tu portador va golpeando aquí y allá con el machete la hiedra.";
vplay sound of machete;
bnw;
say "Poco a poco, va quedando al descubierto un túmulo draconil que aún conserva algo de su antiguo esplendor.";
bnw;
vplay sound of machete;
mostrar entrada al tumulo.
[ Despejar la hiedra si se viste la cota de malla ]
Instead of taking not despejada hiedra when the guantes is worn:
say "Los guantes de cota de malla parece ser suficiente protección para manipular la hiedra.";
bnw;
if the player is icalante or the player is yerk:
say "Tu portador arranca con ellos la hiedra sin mostrar ninguna molestia.";
bnw;
say "Al poco queda al descubierto un túmulo draconil con lo que queda de su antiguo esplendor.";
bnw;
mostrar entrada al tumulo;
otherwise:
say "Sin embargo tu portador no es suficientemente fuerte como para arrancar casi nada de esta vieja hiedra. Tal vez cortándola.".
To mostrar entrada al tumulo:
now hiedra is despejada;
now monticulo is alDescubierto;
now Pantano24 is mapped below Pantano23;
now Pantano24 is mapped inside Pantano23;
now Pantano23 is mapped above Pantano24;
now Pantano23 is mapped outside Pantano24;
move protector to Pantano23;
say "Para tu sorpresa el túmulo tiene un acceso claro a su interior. Pero...";
bnw;
say "...protegida.";
bnw;
say "Un esqueleto hechizado se alza desde el suelo cuando avanzas hacia el acceso.";
bnw;
say "¡Un protector!";
bnw;
say "Habías escuchado historias sobre ellos. Sobre esclavos humanos condenados a vigilar la tumba de sus dueños para siempre. La vieja y gloriosa nigromancia de los sacerdotes dragón.";
bnw;
say "Pero no sólo el esqueleto es el prodigio. Lo circunda una luminiscencia negra, la poderosa magia de negación de la vida.";
bnw;
say "¿Reconocerá en ti a un descendiente de sus señores? ¿Te permitirá descender hacia las profundidades el túmulo?.".